Delete all hyperlinks in one go

[Ricky78]

Hi, I have many shapes with hyperlinks on a page and would like to delete them all in one go rather than one-by-one. Does anyone have a utility/macro or similar for this available? Thx

[Yacine]

Code Select Expand

Sub DeleteAllHyperlinks()
    Dim shp As Visio.Shape
    Dim i As Integer
   
    ' Loop through all top-level shapes on the active page
    For Each shp In ActivePage.Shapes
        ' Delete hyperlinks from last to first to avoid index shifting
        For i = shp.Hyperlinks.Count To 1 Step -1
            shp.Hyperlinks(i).Delete
        Next i
    Next shp
End Sub

Explanation:

Key is to know your object model.

First you record a macro where you do what your future macro shall do.

Code Select Expand

Sub Macro1()

    'Enable diagram services
    Dim DiagramServices As Integer
    DiagramServices = ActiveDocument.DiagramServicesEnabled
    ActiveDocument.DiagramServicesEnabled = visServiceVersion140 + visServiceVersion150

    Dim UndoScopeID1 As Long
    UndoScopeID1 = Application.BeginUndoScope("Insert Hyperlinks")
    Application.ActiveWindow.Page.Shapes.ItemFromID(1).Hyperlinks.ItemU("Row_1").Delete
    Application.EndUndoScope UndoScopeID1, True

    'Restore diagram services
    ActiveDocument.DiagramServicesEnabled = DiagramServices

End Sub

A lot of useless stuff in it. Try to identify the key command:

Application.ActiveWindow.Page.Shapes.ItemFromID(1).Hyperlinks.ItemU("Row_1").Delete

 Application.ActiveWindow.Page.Shapes.ItemFromID(1) is the shape.

 .Hyperlinks.ItemU("Row_1").Delete is the actual command. But it refers to a specific row. So you need to figure out how to generalize it and later iterate over all the rows.

Luckily you got a hint in the form of "shape.Hyperlinks", that's a thing you can look for in the manuals: https://learn.microsoft.com/en-us/office/vba/api/visio.shape.hyperlinks

And you read that hyperlinks is a collection. So why not iterate over it with a for loop. in your editor try hyperlinks(i) or hyperlinks.item(i). Use the debug.print function for the inspection. Hey it worked.

Pack your new code in a loop that covers all the shapes. Done.