Well it didn't take me long to be stumped.

I am trying to delete layers (and all the shapes on them) on a page if the Layer is hidden.

I use the code below but get a Run Time Error "438":
    Object doesn't support this property or method.

What could I be doing worng?

Sub deletelayers()

Dim vsoShape As Visio.Shape
    Dim vsoLayer As Visio.Layer
    For Each vsoLayer In ActiveDocument.Layers  ' This is the line that errors
        If vsoLayer.visible = False Then
            vsoLayer.Delete (True)
        End If
    Next vsoLayer
   
End Sub
(Stumped Again) BiomedMike

1. A document has no layers, but a page has.
2. "visible" is not a property of a layer.

Sub DeleteLayers()
    Dim vsoShape As Visio.Shape
    Dim vsoLayer As Visio.Layer
   
    For Each vsoLayer In ActivePage.Layers
        If Not CBool(vsoLayer.CellsC(visLayerVisible)) Then
            vsoLayer.Delete True
        End If
    Next vsoLayer
End Sub


The Thomas' code looks great, just two cents - you usually need to delete things in reverse order in Visio.
It is not safeguarded against that. If you are deleting things in the same collection you are iterating over (using For Each), bad things may happen.
I would do this:

    Dim vsoLayer As Visio.Layer
    For i = ActivePage.Layers.Count To 1 Step -1
        Set vsoLayer = ActivePage.Layers(i)
        If Not CBool(vsoLayer.CellsC(visLayerVisible)) Then
            vsoLayer.Delete (True)
        End If
    Next

I mean, for example, this code WILL NOT delete all shapes on the page,
like one could expect, but only half of them:

For Each shp in ActivePage.Shapes
  shp.Delete
Next

And in some cases (with some other collections), it could get worse

Good point. Even today I still fall for it almost every time 🙈
Sometimes I do it in two steps:
1. Collect items in Dictionaries in a for each loop
2. Finally loop over the dictionary and delete the items

I think this is totally a fault of Visio API developers.
The API can (and should) be properly protected from stuff like this.

Just to throw a spanner in the works (something I am well qualified to do) you might need to take into account the fact that shapes can be on more than one layer, one (or more) visible, one (or more) invisible. Also grouped shapes can contain sub-shapes that are also independently layered. Your particular application might not need this but for a general purpose routine you would need to take this into account. My 2p.

AMAZING! THANK YOU ALL!

This works PERFECTLY!

I continue to be amazed at the knowledge of you all.

Thank you,

BiomedMike